Formatear números de WhatsApp para HubSpot y Flowella

Si guardas números de WhatsApp en HubSpot para los flujos de trabajo de Flowella, un formato coherente evita envíos fallidos. Esta página explica qué formato usar, qué formatos acepta Flowella, qué propiedad de HubSpot lee Flowella y cómo limpiar una hoja de cálculo de números antes de importarla.

Usa el formato E.164

Guarda todos los números de teléfono de WhatsApp en formato E.164, el estándar internacional para números de teléfono:

Un signo más +
El prefijo de país (sin cero inicial)
El número nacional completo (sin el 0 troncal inicial)

Ejemplos:

Fijo del Reino Unido: +442079460958
Móvil del Reino Unido: +447700900123

Evita espacios, paréntesis y guiones. HubSpot muestra el formato de forma legible en la interfaz, pero los valores E.164 limpios son los más fiables para las integraciones, incluida Flowella.

Formatos que acepta Flowella

Cuando una acción de flujo de trabajo envía un mensaje, Flowella convierte el número guardado a E.164. Ignora los espacios, guiones y paréntesis, pero necesita el prefijo de país.

Valor guardado	Qué hace Flowella
`+44 7700 900123`	Envía a `+447700900123`
`+447700900123`	Envía a `+447700900123`
`0044 7700 900123`	Interpreta `00` como prefijo internacional y envía a `+447700900123`
`447700900123`	Interpreta que el número empieza por un prefijo de país y envía a `+447700900123`
`07700 900123`	Falla con `CONTACT_PHONE_INVALID`, porque no hay prefijo de país

Flowella interpreta un número sin + ni 00 como si empezara por un prefijo de país. En ese caso, un número nacional puede coincidir con el país equivocado. Por ejemplo, el número estadounidense (202) 555-0123 guardado sin +1 se interpreta como un número egipcio que empieza por +20. Incluye siempre el prefijo de país.

¿Qué propiedad de HubSpot contiene el número de WhatsApp?

HubSpot tiene una propiedad específica para el número de teléfono de WhatsApp, hs_whatsapp_phone_number. Flowella la usa primero, antes que las propiedades genéricas Mobile phone number (mobilephone) y Phone number (phone).

Situación	Qué lee o escribe Flowella
Mensaje entrante de alguien que aún no está en HubSpot	Flowella crea un contacto de HubSpot con el número de WhatsApp en `hs_whatsapp_phone_number`. La propiedad genérica `phone` se deja vacía. Requiere la capacidad CRM contacts (auto-create on new WhatsApp chat).
Mensaje entrante de un contacto que ya existe	Flowella busca primero en `hs_whatsapp_phone_number`, después en `mobilephone` y después en `phone`. Cuando encuentra un contacto, escribe el número de WhatsApp en `hs_whatsapp_phone_number` si esa propiedad está vacía o contiene un número diferente.
Send WhatsApp Template o Send WhatsApp Message en un flujo de trabajo de HubSpot	Flowella usa la propiedad de teléfono que asignas en la acción. Si esa propiedad está vacía en el contacto, prueba con `hs_whatsapp_phone_number`, después con `mobilephone` y después con `phone`.
Send WhatsApp Reply en un flujo de trabajo de HubSpot	La acción no tiene campo de teléfono. Flowella siempre prueba con `hs_whatsapp_phone_number`, después con `mobilephone` y después con `phone`.

Si ninguna de estas propiedades contiene un número, la acción falla con CONTACT_PHONE_MISSING. Si el número no se puede leer, falla con CONTACT_PHONE_INVALID. Consulta Códigos de error.

Asigna hs_whatsapp_phone_number en tus acciones de flujo de trabajo. Si tus contactos existentes tienen su número de WhatsApp en phone o mobilephone, cópialo a hs_whatsapp_phone_number con un flujo de trabajo o una importación de HubSpot. Flowella recurre a las otras propiedades, pero la propiedad específica deja claro qué número se usa para WhatsApp.

Comprobar que un número es válido en HubSpot

Cuando haces clic en un campo de teléfono de la ficha de un contacto (por ejemplo, Mobile phone number), HubSpot muestra un estado debajo del campo. Lo que buscas es que muestre Validated. Si no muestra Validated:

Comprueba que el número empiece por + y el prefijo de país correcto
Comprueba que no haya un 0 inicial después del prefijo de país (por ejemplo, +4407… es incorrecto; usa +447…)
Usa la opción Remove number formatting de HubSpot si pegaste un valor desordenado y vuelve a guardar

Comprueba qué propiedad contiene realmente el número con WhatsApp antes de asignarla en una acción de flujo de trabajo. El Phone number de un contacto suele ser un fijo, mientras que su número de WhatsApp puede estar en Mobile phone number o en hs_whatsapp_phone_number.

Consejos para importar desde CSV y Excel

Excel intentará “ayudar” eliminando el signo + o convirtiendo los números largos en notación científica. Evítalo antes de importar:

Da formato Text a la columna de teléfono (Home → Number format → Text) y después pega los valores
O añade un apóstrofo delante de los valores en Excel: '+447700900123. El apóstrofo obliga a tratar el valor como texto y no aparece en los datos importados
En los archivos CSV, pon los valores entre comillas: "+447700900123"

No importes números con espacios ni paréntesis. HubSpot a menudo puede normalizar el formato, pero los valores E.164 limpios dan los resultados más coherentes.

Fórmula de Excel: limpiar números de teléfono a E.164

Si tienes una hoja de cálculo llena de números de teléfono en distintos formatos, la fórmula siguiente los limpia y los convierte al formato E.164, listos para importarlos en HubSpot. Admite todos los formatos de entrada habituales, entre ellos:

Números locales con un 0 inicial (p. ej., 07700 900123)
Números con + y prefijo de país (p. ej., +44 7700 900123)
El prefijo de marcación internacional 00 (p. ej., 0044 7700 900123)
El formato +44(0)7...
Guiones, puntos, paréntesis y otros signos de puntuación
Números que ya tienen el prefijo de país pero no el + (p. ej., 447700900123)

Esta fórmula requiere Excel 365 o Google Sheets. Usa LET, TEXTJOIN y SEQUENCE, que no están disponibles en versiones anteriores de Excel.

Cómo usar la fórmula

Copia la fórmula siguiente
Pégala en cualquier celda de tu hoja de cálculo
Cambia A2 para que apunte a la primera celda con un número de teléfono
Cambia "44" por tu prefijo de país (consulta la tabla de referencia más abajo)
Cambia 10 por la longitud esperada de los números móviles de tu país
Pulsa Intro y arrastra hacia abajo para aplicarla a todas las filas

La fórmula

=LET(
  cell, A2,
  country_code, "44",
  nsn_len, 10,
  raw, TRIM(cell&""),
  clean, SUBSTITUTE(raw,"(0)",""),
  digits, TEXTJOIN("",,IFERROR(MID(clean,SEQUENCE(LEN(clean)),1)*1,"")),
  has_plus, ISNUMBER(FIND("+",raw)),
  has_00, LEFT(digits,2)="00",
  p, LEN(country_code),
  starts_cc, AND(LEFT(digits,p)=country_code, LEN(digits)=p+nsn_len),
  nsn, IF(has_plus, digits,
    IF(has_00, MID(digits,3,999),
    IF(starts_cc, MID(digits,p+1,999),
    IF(LEFT(digits,1)="0", MID(digits,2,999), digits)))),
  intl, IF(has_plus, "+"&digits,
    IF(has_00, "+"&MID(digits,3,999),
    IF(starts_cc, "+"&digits,
    "+"&country_code&nsn))),
  is_domestic, AND(NOT(has_plus), NOT(has_00), NOT(starts_cc)),
  IF(raw="","",
  IF(digits="","REVIEW (not a number): "&raw,
  IF(AND(is_domestic, LEN(nsn)<nsn_len),"REVIEW (number too short): "&raw,
  IF(AND(is_domestic, LEN(nsn)>nsn_len),"REVIEW (number too long): "&raw,
  intl))))
)

Qué significan las tres variables de configuración

Variable	Qué cambiar
`cell`	La celda que contiene el número de teléfono sin procesar. Cámbiala para que coincida con tu columna (p. ej., `G2`)
`country_code`	El prefijo de país predeterminado para los números nacionales (p. ej., `"44"` para el Reino Unido, `"1"` para EE. UU.)
`nsn_len`	La longitud esperada del número nacional de abonado para los móviles de tu país (p. ej., `10` para el Reino Unido y EE. UU.)

Cómo funciona la fórmula

La fórmula sigue cuatro caminos distintos según lo que encuentre en el valor de entrada:

Tiene + en el original: ya es internacional. Deja solo los dígitos y antepone +
Empieza por 00: prefijo de marcación internacional. Elimina el 00 y antepone +
Empieza por el prefijo de país Y el número de dígitos coincide: internacional sin + (p. ej., 447700900123). Antepone +
Todo lo demás: número nacional. Elimina el 0 inicial y antepone + y el prefijo de país

Antes de todo esto, la fórmula elimina (0) del valor de entrada, de modo que +44(0)7700 900123 se procesa correctamente.

Resultado para números no válidos

Los números que no superan la validación devuelven un mensaje claro para que puedas filtrarlos y corregirlos:

Resultado	Significado
`REVIEW (not a number): hello world`	No se ha encontrado ningún dígito
`REVIEW (number too short): 07700`	No hay suficientes dígitos para un número válido
`REVIEW (number too long): 077009001234`	Demasiados dígitos, posiblemente un prefijo duplicado

La validación de longitud solo se aplica a los números nacionales (los que no tienen + ni 00). Los números que ya tienen un prefijo internacional se devuelven tal cual, ya que la fórmula no puede conocer la longitud del número nacional de abonado de cada país.

Referencia de prefijos de país

País	Prefijo de país	Longitud del número nacional (móvil)	Notas
Reino Unido	44	10
Estados Unidos / Canadá	1	10	Todos los países del NANP comparten cc=1
Francia	33	9
Alemania	49	11	Solo móviles; los fijos varían
España	34	9
Italia	39	10	Los móviles conservan el 3 inicial
Portugal	351	9
Países Bajos	31	9
Irlanda	353	9
Grecia	30	10
Polonia	48	9
Suiza	41	9
Turquía	90	10
India	91	10
Australia	61	9
Japón	81	10
China	86	11
Emiratos Árabes Unidos	971	9
Arabia Saudí	966	9
Sudáfrica	27	9
Brasil	55	11	Móviles con el noveno dígito
Singapur	65	8
Hong Kong	852	8

Los valores de longitud anteriores corresponden a números móviles. Para WhatsApp, las longitudes de móvil son las correctas. Si procesas una mezcla de móviles y fijos, ten en cuenta que algunos países (sobre todo Alemania) tienen fijos de longitud variable.

Lista rápida de comprobación

Si tus acciones de flujo de trabajo de Flowella fallan con CONTACT_PHONE_MISSING o CONTACT_PHONE_INVALID, revisa esta lista:

Confirma que la propiedad de HubSpot contiene un valor en formato E.164 (empieza por +)
Confirma que el campo muestra el estado Validated en HubSpot
Asegúrate de que el número incluye el prefijo de país y no tiene un 0 inicial después
Asegúrate de que tu acción de flujo de trabajo apunta a la propiedad que contiene realmente el número con WhatsApp, idealmente hs_whatsapp_phone_number
Si la propiedad asignada está vacía, revisa las propiedades alternativas en el orden en que las lee Flowella: hs_whatsapp_phone_number, mobilephone, phone

Relacionado

Conectar HubSpot

Conecta tu cuenta de HubSpot y comprueba tus capacidades.

Acciones de flujo de trabajo

Elige la propiedad de teléfono correcta al configurar Send WhatsApp Template.

Fallos de sincronización con HubSpot

Los problemas de formato del teléfono son la causa más habitual de los envíos fallidos.

Mensajes no entregados

Diagnostica envíos concretos que no llegan al destinatario.

Primeros pasos

Esenciales

Uso de la aplicación

Configuración

Configuración de Meta y WhatsApp

Integraciones

Flujos y campañas

Referencia de API

Solución de problemas

Registro de cambios

Formatear números de WhatsApp para HubSpot y Flowella

Usa el formato E.164

Formatos que acepta Flowella

¿Qué propiedad de HubSpot contiene el número de WhatsApp?

Comprobar que un número es válido en HubSpot

Consejos para importar desde CSV y Excel

Fórmula de Excel: limpiar números de teléfono a E.164

Cómo usar la fórmula

La fórmula

Qué significan las tres variables de configuración

Cómo funciona la fórmula

Resultado para números no válidos

Referencia de prefijos de país

Lista rápida de comprobación

Relacionado

Conectar HubSpot

Acciones de flujo de trabajo

Fallos de sincronización con HubSpot

Mensajes no entregados