Formatar números de telefone WhatsApp para o HubSpot e o Flowella

Se guarda números WhatsApp no HubSpot para workflows do Flowella, uma formatação consistente evita envios falhados. Esta página explica o formato a usar, que formatos o Flowella aceita, que propriedade do HubSpot o Flowella lê e como limpar uma folha de cálculo de números antes de a importar.

Usar o formato E.164

Guarde todos os números de telefone WhatsApp no formato E.164, a norma internacional para números de telefone:

Um sinal de mais +
Indicativo do país (sem zero inicial)
Número nacional completo (sem o 0 de prefixo nacional)

Exemplos:

Telefone fixo do Reino Unido: +442079460958
Telemóvel do Reino Unido: +447700900123

Evite espaços, parênteses e hífenes. O HubSpot apresenta a formatação de forma legível na interface, mas valores E.164 limpos são os mais fiáveis para integrações, incluindo o Flowella.

Formatos que o Flowella aceita

Quando uma ação de workflow envia uma mensagem, o Flowella converte o número guardado para E.164. Ignora espaços, hífenes e parênteses, mas precisa do indicativo do país.

Valor guardado	O que o Flowella faz
`+44 7700 900123`	Envia para `+447700900123`
`+447700900123`	Envia para `+447700900123`
`0044 7700 900123`	Lê `00` como prefixo internacional e envia para `+447700900123`
`447700900123`	Lê o número como começando por um indicativo do país e envia para `+447700900123`
`07700 900123`	Falha com `CONTACT_PHONE_INVALID`, porque não tem indicativo do país

O Flowella lê um número sem + ou 00 como se começasse por um indicativo do país. Um número nacional pode então corresponder ao país errado. Por exemplo, o número dos EUA (202) 555-0123 guardado sem +1 é lido como um número egípcio começado por +20. Inclua sempre o indicativo do país.

Que propriedade do HubSpot guarda o número WhatsApp?

O HubSpot tem uma propriedade dedicada ao número de telefone WhatsApp, hs_whatsapp_phone_number. O Flowella usa-a primeiro, antes das propriedades genéricas Mobile phone number (mobilephone) e Phone number (phone).

Cenário	O que o Flowella lê ou escreve
Mensagem recebida de alguém que ainda não está no HubSpot	O Flowella cria um contacto HubSpot com o número WhatsApp em `hs_whatsapp_phone_number`. A propriedade genérica `phone` fica vazia. Isto requer a capacidade CRM contacts (auto-create on new WhatsApp chat).
Mensagem recebida de um contacto que já existe	O Flowella procura primeiro em `hs_whatsapp_phone_number`, depois em `mobilephone` e depois em `phone`. Quando encontra um contacto correspondente, escreve o número WhatsApp em `hs_whatsapp_phone_number` se essa propriedade estiver vazia ou tiver um número diferente.
Send WhatsApp Template ou Send WhatsApp Message num workflow do HubSpot	O Flowella usa a propriedade de telefone que mapeia na ação. Se essa propriedade estiver vazia no contacto, tenta `hs_whatsapp_phone_number`, depois `mobilephone` e depois `phone`.
Send WhatsApp Reply num workflow do HubSpot	A ação não tem campo de telefone. O Flowella tenta sempre `hs_whatsapp_phone_number`, depois `mobilephone` e depois `phone`.

Se nenhuma destas propriedades tiver um número, a ação falha com CONTACT_PHONE_MISSING. Se o número não puder ser lido, falha com CONTACT_PHONE_INVALID. Consulte Códigos de erro.

Mapeie hs_whatsapp_phone_number nas suas ações de workflow. Se os seus contactos existentes tiverem o número WhatsApp em phone ou mobilephone, copie-o para hs_whatsapp_phone_number com um workflow ou uma importação do HubSpot. O Flowella recorre às outras propriedades, mas a propriedade dedicada deixa claro que número é usado para o WhatsApp.

Verificar se um número é válido no HubSpot

Quando clica num campo de telefone de um registo de contacto (por exemplo, Mobile phone number), o HubSpot mostra um estado por baixo do campo. Deve aparecer Validated. Se não aparecer Validated:

Confirme que o número começa por + e pelo indicativo do país correto
Confirme que não há um 0 inicial depois do indicativo do país (por exemplo, +4407… está errado; use +447…)
Use a opção Remove number formatting do HubSpot se colou um valor desorganizado e volte a guardar

Verifique que propriedade contém realmente o número com WhatsApp antes de a mapear numa ação de workflow. O Phone number de um contacto é muitas vezes um telefone fixo, enquanto o número WhatsApp pode estar em Mobile phone number ou em hs_whatsapp_phone_number.

Dicas para importação de CSV e Excel

O Excel vai “ajudar” removendo o sinal + ou convertendo números longos em notação científica. Evite isto antes de importar:

Formate a coluna de telefone como Text (Home → Number format → Text) e só depois cole os valores
Ou adicione um apóstrofo antes dos valores no Excel: '+447700900123. O apóstrofo força o tratamento como texto e não aparece nos dados importados
Em ficheiros CSV, coloque os valores entre aspas: "+447700900123"

Não importe números com espaços ou parênteses. O HubSpot consegue muitas vezes normalizar a formatação, mas valores E.164 limpos dão os resultados mais consistentes.

Fórmula Excel: limpar números de telefone para E.164

Se tiver uma folha de cálculo cheia de números de telefone em vários formatos, a fórmula abaixo limpa-os para o formato E.164, prontos para importar no HubSpot. Trata todos os formatos de entrada comuns, incluindo:

Números locais com um 0 inicial (por exemplo, 07700 900123)
Números com + e indicativo do país (por exemplo, +44 7700 900123)
Prefixo de marcação internacional 00 (por exemplo, 0044 7700 900123)
O formato +44(0)7...
Hífenes, pontos, parênteses e outra pontuação
Números que já têm o indicativo do país mas não têm + (por exemplo, 447700900123)

Esta fórmula requer o Excel 365 ou o Google Sheets. Usa LET, TEXTJOIN e SEQUENCE, que não estão disponíveis em versões mais antigas do Excel.

Como usar a fórmula

Copie a fórmula abaixo
Cole-a em qualquer célula da sua folha de cálculo
Altere A2 para apontar para a célula do seu primeiro número de telefone
Altere "44" para o indicativo do seu país (consulte a tabela de referência abaixo)
Altere 10 para o comprimento esperado dos números de telemóvel no seu país
Prima Enter e arraste para baixo para aplicar a todas as linhas

A fórmula

=LET(
  cell, A2,
  country_code, "44",
  nsn_len, 10,
  raw, TRIM(cell&""),
  clean, SUBSTITUTE(raw,"(0)",""),
  digits, TEXTJOIN("",,IFERROR(MID(clean,SEQUENCE(LEN(clean)),1)*1,"")),
  has_plus, ISNUMBER(FIND("+",raw)),
  has_00, LEFT(digits,2)="00",
  p, LEN(country_code),
  starts_cc, AND(LEFT(digits,p)=country_code, LEN(digits)=p+nsn_len),
  nsn, IF(has_plus, digits,
    IF(has_00, MID(digits,3,999),
    IF(starts_cc, MID(digits,p+1,999),
    IF(LEFT(digits,1)="0", MID(digits,2,999), digits)))),
  intl, IF(has_plus, "+"&digits,
    IF(has_00, "+"&MID(digits,3,999),
    IF(starts_cc, "+"&digits,
    "+"&country_code&nsn))),
  is_domestic, AND(NOT(has_plus), NOT(has_00), NOT(starts_cc)),
  IF(raw="","",
  IF(digits="","REVIEW (not a number): "&raw,
  IF(AND(is_domestic, LEN(nsn)<nsn_len),"REVIEW (number too short): "&raw,
  IF(AND(is_domestic, LEN(nsn)>nsn_len),"REVIEW (number too long): "&raw,
  intl))))
)

O que significam as três variáveis de configuração

Variável	O que alterar
`cell`	A célula que contém o número de telefone original. Altere-a para corresponder à sua coluna (por exemplo, `G2`)
`country_code`	O indicativo do país predefinido para números nacionais (por exemplo, `"44"` para o Reino Unido, `"1"` para os EUA)
`nsn_len`	O comprimento esperado do número nacional de assinante para telemóveis no seu país (por exemplo, `10` para o Reino Unido e os EUA)

Como funciona a fórmula

A fórmula segue quatro caminhos diferentes consoante o que encontra no valor de entrada:

Tem + no original: já é internacional. Fica apenas com os dígitos e acrescenta + no início
Começa por 00: prefixo de marcação internacional. Remove o 00 e acrescenta + no início
Começa pelo indicativo do país E o número de dígitos corresponde: internacional sem prefixo (por exemplo, 447700900123). Acrescenta + no início
Tudo o resto: número nacional. Remove o 0 inicial e acrescenta + e o indicativo do país no início

Antes de tudo isto, a fórmula remove (0) do valor original, por isso +44(0)7700 900123 é tratado corretamente.

Resultado para números inválidos

Os números que não passam a validação devolvem uma mensagem clara para que os possa filtrar e corrigir:

Resultado	Significado
`REVIEW (not a number): hello world`	Não foram encontrados dígitos
`REVIEW (number too short): 07700`	Dígitos insuficientes para um número válido
`REVIEW (number too long): 077009001234`	Dígitos a mais, possivelmente um prefixo duplicado

A validação do comprimento só se aplica a números nacionais (os que não têm + ou 00). Os números que já têm um prefixo internacional passam sem alterações, porque a fórmula não pode saber o comprimento do NSN de todos os países.

Referência de indicativos de país

País	Indicativo do país	Comprimento do NSN (telemóvel)	Notas
Reino Unido	44	10
Estados Unidos / Canadá	1	10	Todos os países NANP partilham cc=1
França	33	9
Alemanha	49	11	Apenas telemóveis; os fixos variam
Espanha	34	9
Itália	39	10	Os telemóveis mantêm o 3 inicial
Portugal	351	9
Países Baixos	31	9
Irlanda	353	9
Grécia	30	10
Polónia	48	9
Suíça	41	9
Turquia	90	10
Índia	91	10
Austrália	61	9
Japão	81	10
China	86	11
Emirados Árabes Unidos	971	9
Arábia Saudita	966	9
África do Sul	27	9
Brasil	55	11	Telemóvel com o 9.º dígito
Singapura	65	8
Hong Kong	852	8

Os comprimentos de NSN acima são para números de telemóvel. Para uso no WhatsApp, os comprimentos de telemóvel são os corretos. Se estiver a processar uma mistura de números de telemóvel e fixos, tenha em conta que alguns países (sobretudo a Alemanha) têm números fixos de comprimento variável.

Lista de verificação rápida para resolução de problemas

Se as suas ações de workflow do Flowella estiverem a falhar com CONTACT_PHONE_MISSING ou CONTACT_PHONE_INVALID, siga esta lista de verificação:

Confirme que a propriedade do HubSpot contém um valor no formato E.164 (começa por +)
Confirme que o campo mostra o estado Validated no HubSpot
Certifique-se de que o número inclui o indicativo do país e não tem um 0 inicial a seguir
Certifique-se de que a sua ação de workflow aponta para a propriedade que contém realmente o número com WhatsApp, idealmente hs_whatsapp_phone_number
Se a propriedade mapeada estiver vazia, verifique as propriedades alternativas pela ordem em que o Flowella as lê: hs_whatsapp_phone_number, mobilephone, phone

Relacionado

Ligar o HubSpot

Ligue a sua conta HubSpot e verifique as suas capacidades.

Ações de workflow

Escolha a propriedade de telefone certa ao configurar Send WhatsApp Template.

Falhas de sincronização do HubSpot

Os problemas de formato do telefone são a causa mais comum de envios falhados.

Mensagens não entregues

Diagnostique envios individuais que não chegam ao destinatário.

Primeiros passos

Essenciais

Usar a aplicação

Definições

Configuração Meta e WhatsApp

Integração HubSpot

Flows e campanhas

Referência da API

Resolução de problemas

Registro de alterações

Formatar números de telefone WhatsApp para o HubSpot e o Flowella

Usar o formato E.164

Formatos que o Flowella aceita

Que propriedade do HubSpot guarda o número WhatsApp?

Verificar se um número é válido no HubSpot

Dicas para importação de CSV e Excel

Fórmula Excel: limpar números de telefone para E.164

Como usar a fórmula

A fórmula

O que significam as três variáveis de configuração

Como funciona a fórmula

Resultado para números inválidos

Referência de indicativos de país

Lista de verificação rápida para resolução de problemas

Relacionado

Ligar o HubSpot

Ações de workflow

Falhas de sincronização do HubSpot

Mensagens não entregues

​Usar o formato E.164

​Formatos que o Flowella aceita

​Que propriedade do HubSpot guarda o número WhatsApp?

​Verificar se um número é válido no HubSpot

​Dicas para importação de CSV e Excel

​Fórmula Excel: limpar números de telefone para E.164

​Como usar a fórmula

​A fórmula

​O que significam as três variáveis de configuração

​Como funciona a fórmula

​Resultado para números inválidos

​Referência de indicativos de país

​Lista de verificação rápida para resolução de problemas

​Relacionado

Ligar o HubSpot

Ações de workflow

Falhas de sincronização do HubSpot

Mensagens não entregues

Usar o formato E.164

Formatos que o Flowella aceita

Que propriedade do HubSpot guarda o número WhatsApp?

Verificar se um número é válido no HubSpot

Dicas para importação de CSV e Excel

Fórmula Excel: limpar números de telefone para E.164

Como usar a fórmula

A fórmula

O que significam as três variáveis de configuração

Como funciona a fórmula

Resultado para números inválidos

Referência de indicativos de país

Lista de verificação rápida para resolução de problemas

Relacionado